From 386f459b3a5e0a2b8b9c15ef1bb63f2f9c2580ba Mon Sep 17 00:00:00 2001
From: Xavier <sapphirus@azorium.net>
Date: Fri, 8 Mar 2024 01:08:50 -0500
Subject: [PATCH] Initial commit

---
 .SRCINFO | 33 +++++++++++++++++++++++++++++
 PKGBUILD | 63 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 .SRCINFO
 create mode 100644 PKGBUILD

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000..be2173b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = pacwrap-git
+	pkgdesc = Facilitates the creation, management, and execution of unprivileged Arch-based bubblewrap containers.
+	pkgver = 0.7.2.r14.8f419c0
+	pkgrel = 1
+	url = https://pacwrap.sapphirus.org/
+	arch = x86_64
+	license = GPLv3-only
+	makedepends = cargo
+	makedepends = git
+	makedepends = fakeroot
+	makedepends = pacman
+	makedepends = zstd
+	makedepends = busybox
+	makedepends = fakechroot
+	options = !lto
+	source = pacwrap::git+https://github.com/pacwrap/pacwrap.git
+	md5sums = SKIP
+
+pkgname = pacwrap-git
+	depends = bash
+	depends = bubblewrap
+	depends = gnupg
+	depends = pacman
+	depends = libseccomp
+	depends = =0.7.2.r14.8f419c0
+	depends = zstd
+	optdepends = xdg-dbus-proxy
+	provides = pacwrap
+	conflicts = pacwrap
+
+pkgname = pacwrap-dist-git
+	provides = pacwrap-dist
+	conflicts = pacwrap-dist
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..0f44efe
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,63 @@
+# Maintainer: Xavier R.M. (sapphirus at azorium dot net)
+
+_pkgname=pacwrap
+pkgname=('pacwrap-git' 'pacwrap-dist-git')
+pkgver=0.7.2.r14.8f419c0
+pkgrel=1
+_pkgbase=$_pkgname
+pkgdesc="Facilitates the creation, management, and execution of unprivileged Arch-based bubblewrap containers."
+arch=('x86_64')
+url="https://pacwrap.sapphirus.org/"
+license=('GPLv3-only')
+makedepends=('cargo' 'git' 'fakeroot' 'pacman' 'zstd' 'busybox' 'fakechroot')
+source=("$_pkgname::git+https://github.com/pacwrap/pacwrap.git")
+md5sums=('SKIP')
+options=('!lto')
+
+pkgver() {
+    	cd $_pkgbase
+	echo "$(git describe --tags | sed 's/^v//; s/-/.r/; s/-g/./')"
+}
+
+prepare() {
+	cd "${_pkgbase}" 	
+  	cargo fetch --locked --target "$CARCH-unknown-linux-gnu" \
+	&& ./dist/tools/prepare.sh release
+}
+
+build() {
+  	cd "${_pkgbase}"
+	PACWRAP_SCHEMA_BUILT=1 \
+	cargo build --release --frozen \
+	&& ./dist/tools/package.sh release
+}
+
+package_pacwrap-git() {
+	provides=("${_pkgname}")
+	conflicts=("${_pkgname}")
+	depends=('bash' 'bubblewrap' 'gnupg' 'pacman' 'libseccomp' "${pkgname[1]}=$pkgver" 'zstd')
+	optdepends=('xdg-dbus-proxy')
+
+  	cd "${_pkgbase}"
+
+	install -d "${pkgdir}/usr/share/${_pkgname}"	
+	install -Dm 755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  	install -Dm 755 "dist/bin/${_pkgname}-key" "${pkgdir}/usr/bin/${_pkgname}-key"
+	install -Dm 644 "dist/bin/${_pkgname}.1" "${pkgdir}/usr/share/man/man1/${_pkgname}.1"
+	install -Dm 644 "dist/bin/${_pkgname}.yml.2" "${pkgdir}/usr/share/man/man2/pcwrap.yml.2"
+	install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+}
+
+package_pacwrap-dist-git() {
+	provides=("${_pkgname}-dist")
+	conflicts=("${_pkgname}-dist")
+
+  	cd "${_pkgbase}"
+
+	install -dD 755 "${pkgdir}/usr/share/${_pkgname}/"
+	install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}-dist/LICENSE"
+	install -Dm 644 "dist/bin/filesystem.tar.zst" "${pkgdir}/usr/share/${_pkgname}/filesystem.tar.zst"
+	install -Dm 644 "dist/bin/filesystem.dat" "${pkgdir}/usr/share/${_pkgname}/filesystem.dat"
+
+	cp -r "dist/runtime" "${pkgdir}/usr/share/${_pkgname}/"
+}